Upgrade CMake practices

.github/workflows/macos-build.yml

@@ -45,7 +45,7 @@ jobs:
           echo BUILD_UNIVERSAL=1 >> $GITHUB_ENV
 
       - name: Install Boost
-        run: ./install-boost.sh
+        run: ./install-boost.sh --download --build
 
       - name: Check submodules
         run: git submodule > submodule-status

.github/workflows/windows-build.yml

@@ -24,6 +24,7 @@ jobs:
           - { compiler: msvc, arch: x86, cross_arch: x64_x86 }
     env:
       boost_version: 1.89.0
+      BOOST_TOOLSET: ${{ matrix.compiler == 'clang' && 'clang-win' || 'msvc' }}
       BOOST_ROOT: ${{ github.workspace }}\deps\boost-1.89.0
       RIME_PLUGINS: ${{ inputs.rime_plugins }}
 
@@ -66,7 +67,7 @@ jobs:
           git submodule > submodule-status
 
       - name: Install boost
-        run: .\install-boost.bat
+        run: .\install-boost.bat --build
 
       - name: Cache dependencies
         id: cache-deps
@@ -153,16 +154,12 @@ jobs:
             -DCMAKE_INSTALL_PREFIX:PATH=`pwd`/dist \
             -DCMAKE_BUILD_TYPE:STRING=Release \
             -DENABLE_LOGGING:BOOL=ON \
-            -DBUILD_TEST:BOOL=ON \
-            -DBUILD_STATIC:BOOL=ON \
+            -DBUILD_TESTING:BOOL=ON \
+            -DWITH_STATIC_DEPS:BOOL=ON \
             -DBUILD_SHARED_LIBS:BOOL=ON
           cmake --build build
           cmake --install build
-          # Temporarily disable test for mingw-w64
-          # due to msys2 glog package issue:
-          # https://github.com/msys2/MINGW-packages/issues/25344
-          # cd build && cp ./bin/librime.dll ./test
-          # ctest --output-on-failure
+          ctest --output-on-failure
 
       - name: Create distributable
         run: |

CMakeLists.txt

@@ -1,26 +1,30 @@
+cmake_minimum_required(VERSION 3.13)
+
 set(CMAKE_USER_MAKE_RULES_OVERRIDE ${CMAKE_CURRENT_SOURCE_DIR}/cmake/c_flag_overrides.cmake)
 set(CMAKE_USER_MAKE_RULES_OVERRIDE_CXX ${CMAKE_CURRENT_SOURCE_DIR}/cmake/cxx_flag_overrides.cmake)
 
-cmake_minimum_required(VERSION 3.12)
-project(rime)
-set(CMAKE_CXX_STANDARD 17)
-
 set(rime_version 1.16.0)
 set(rime_soversion 1)
 
+project(rime VERSION ${rime_version})
+
+set(CMAKE_CXX_STANDARD 17)
+set(CMAKE_CXX_STANDARD_REQUIRED ON)
+set(CMAKE_CXX_EXTENSIONS OFF)
+
 add_definitions(-DRIME_VERSION="${rime_version}")
 
 # generate compile_commands.json
 set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
 
 include(GNUInstallDirs)
+include(CMakePackageConfigHelpers)
 
 option(BUILD_SHARED_LIBS "Build Rime as shared library" ON)
 option(BUILD_MERGED_PLUGINS "Merge plugins into one Rime library" ON)
-option(BUILD_STATIC "Build with dependencies as static libraries" OFF)
-option(BUILD_DATA "Build data for Rime" OFF)
+option(WITH_STATIC_DEPS "Build with static dependency libraries" OFF)
 option(BUILD_SAMPLE "Build sample Rime plugin" OFF)
-option(BUILD_TEST "Build and run tests" ON)
+option(BUILD_TESTING "Build and run tests" ON)
 option(BUILD_SEPARATE_LIBS "Build separate rime-* libraries" OFF)
 option(ENABLE_LOGGING "Enable logging with google-glog library" ON)
 option(ALSO_LOG_TO_STDERR "Log to stderr as well as log file" OFF)
@@ -33,56 +37,25 @@ option(ENABLE_TIMESTAMP "Embed timestamp to schema artifacts" ON)
 set(RIME_DATA_DIR "rime-data" CACHE STRING "Target directory for Rime data")
 set(RIME_PLUGINS_DIR "rime-plugins" CACHE STRING "Target directory for externally built Rime plugins")
 
-if(WIN32)
-  set(ext ".exe")
-endif(WIN32)
-
 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${PROJECT_SOURCE_DIR}/cmake")
 set(CMAKE_PREFIX_PATH ${CMAKE_PREFIX_PATH} "${PROJECT_SOURCE_DIR}")
 
-if (ENABLE_ASAN)
-  set(asan_cflags "-fsanitize=address -fno-omit-frame-pointer")
-  set(asan_lflags "-fsanitize=address -lasan")
-  set(CMAKE_C_FLAGS "${asan_cflags} ${CMAKE_C_FLAGS}")
-  set(CMAKE_CXX_FLAGS "${asan_cflags} ${CMAKE_CXX_FLAGS}")
-  set(CMAKE_EXE_LINKER_FLAGS "${asan_lflags} ${CMAKE_EXE_LINKER_FLAGS}")
-  set(CMAKE_SHARED_LINKER_FLAGS "${asan_lflags} ${CMAKE_SHARED_LINKER_FLAGS}")
+if(ENABLE_ASAN)
+  add_compile_options(-fsanitize=address -fno-omit-frame-pointer)
+  add_link_options(-fsanitize=address -lasan)
 endif()
 
-set(Boost_USE_STATIC_LIBS ${BUILD_STATIC})
-set(Gflags_STATIC ${BUILD_STATIC})
-set(Glog_STATIC ${BUILD_STATIC})
-set(LevelDb_STATIC ${BUILD_STATIC})
-set(Marisa_STATIC ${BUILD_STATIC})
-set(Opencc_STATIC ${BUILD_STATIC})
-set(YamlCpp_STATIC ${BUILD_STATIC})
 
-set(Boost_USE_MULTITHREADED ON)
-if(MSVC)
-  set(Boost_USE_STATIC_RUNTIME ON)
-endif()
+find_package(Boost CONFIG 1.74.0 REQUIRED COMPONENTS regex)
 
-if(LINUX)
-  find_package(Boost 1.74.0 REQUIRED COMPONENTS regex)
-else()
-  find_package(Boost 1.77.0)
-endif()
-if(Boost_FOUND)
-  include_directories(${Boost_INCLUDE_DIRS})
-  link_directories(${Boost_LIBRARY_DIRS})
-  add_definitions(-DBOOST_DLL_USE_STD_FS)
-endif()
+add_definitions(-DBOOST_DLL_USE_STD_FS)
+set(Boost_USE_STATIC_LIBS ${WITH_STATIC_DEPS})
+set(Boost_USE_MULTITHREADED ON)
 
 if(ENABLE_LOGGING)
-
-  find_package(Gflags)
-  if(Gflags_FOUND)
-    include_directories(${Gflags_INCLUDE_PATH})
-  endif()
-
-  find_package(Glog REQUIRED)
+  find_package(GFlags CONFIG QUIET)
+  find_package(GLog CONFIG REQUIRED)
   if(Glog_FOUND)
-    include_directories(${Glog_INCLUDE_PATH})
     if(WIN32)
       add_compile_definitions("GLOG_DEPRECATED=__declspec(deprecated)")
       add_compile_definitions(GLOG_NO_ABBREVIATED_SEVERITIES)
@@ -96,15 +69,20 @@ if(ENABLE_LOGGING)
       add_compile_definitions("GLOG_EXPORT=__attribute__((visibility(\"default\")))")
       add_compile_definitions("GLOG_NO_EXPORT=__attribute__((visibility(\"default\")))")
     endif()
-  endif()
 
-  set(RIME_ENABLE_LOGGING 1)
+    if(WITH_STATIC_DEPS)
+      add_definitions(-DGOOGLE_GLOG_DLL_DECL=)
+    endif()
+
+    set(RIME_ENABLE_LOGGING 1)
 
-  if (ALSO_LOG_TO_STDERR)
-     set(RIME_ALSO_LOG_TO_STDERR 1)
+    if(ALSO_LOG_TO_STDERR)
+      set(RIME_ALSO_LOG_TO_STDERR 1)
+    endif()
   endif()
 endif()
 
+find_package(Iconv)
 find_package(Threads)
 
 if(NOT ENABLE_THREADING)
@@ -115,37 +93,25 @@ if(NOT ENABLE_TIMESTAMP)
   add_definitions(-DRIME_NO_TIMESTAMP)
 endif()
 
-if(BUILD_TEST)
-  find_package(GTest REQUIRED)
-  if(GTEST_FOUND)
-    enable_testing()
-    include_directories(${GTEST_INCLUDE_DIRS})
-  endif()
+if(BUILD_TESTING)
+  find_package(GTest CONFIG REQUIRED)
 endif()
 
-find_package(YamlCpp REQUIRED)
-if(YamlCpp_FOUND)
-  include_directories(${YamlCpp_INCLUDE_PATH})
-endif()
-if(YamlCpp_STATIC)
+find_package(yaml-cpp CONFIG REQUIRED)
+if(WITH_STATIC_DEPS)
   add_definitions(-DYAML_CPP_STATIC_DEFINE)
 endif()
 
-find_package(LevelDb REQUIRED)
-if(LevelDb_FOUND)
-    include_directories(${LevelDb_INCLUDE_PATH})
-endif()
+find_package(leveldb CONFIG REQUIRED)
 
-find_package(Marisa REQUIRED)
-if(Marisa_FOUND)
-  include_directories(${Marisa_INCLUDE_PATH})
+# debian 12 used in docker CI and ubuntu 24 Linux in CI do not have Marisa cmake config file
+find_package(Marisa CONFIG QUIET)
+if(NOT Marisa_FOUND)
+  find_package(Marisa MODULE REQUIRED)
 endif()
 
-find_package(Opencc REQUIRED)
-if(Opencc_FOUND)
-include_directories(${Opencc_INCLUDE_PATH})
-endif()
-if(Opencc_STATIC)
+find_package(OpenCC CONFIG QUIET)
+if(WITH_STATIC_DEPS)
   add_definitions(-DOpencc_BUILT_AS_STATIC)
 endif()
 
@@ -177,25 +143,21 @@ if(MSVC)
   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /LARGEADDRESSAWARE")
 endif()
 
-if(UNIX)
-  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++17")
-endif()
-
-if (NOT CMAKE_BUILD_PARALLEL_LEVEL)
+if(NOT CMAKE_BUILD_PARALLEL_LEVEL)
   include(ProcessorCount)
   ProcessorCount(N)
-  if (NOT N EQUAL 0)
+  if(NOT N EQUAL 0)
     set(CMAKE_BUILD_PARALLEL_LEVEL ${N})
   endif()
 endif()
 
 # keep these variables lest some Rime plugin's cmake file is still using them {
 if(NOT DEFINED LIB_INSTALL_DIR)
-    set(LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR})
+  set(LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR})
 endif()
 
 if(NOT DEFINED BIN_INSTALL_DIR)
-    set(BIN_INSTALL_DIR ${CMAKE_INSTALL_BINDIR})
+  set(BIN_INSTALL_DIR ${CMAKE_INSTALL_BINDIR})
 endif()
 # }
 
@@ -207,29 +169,39 @@ configure_file(
 add_custom_target(remove
   COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)
 
-if(${CMAKE_SYSTEM_NAME} MATCHES "Linux|FreeBSD|OpenBSD|DragonFly|GNU|Darwin" OR MINGW)
-  set(prefix "${CMAKE_INSTALL_PREFIX}")
-  set(exec_prefix "${CMAKE_INSTALL_PREFIX}")
-  set(bindir "${CMAKE_INSTALL_FULL_BINDIR}")
-  set(libdir "${CMAKE_INSTALL_FULL_LIBDIR}")
-  set(pkgdatadir "${CMAKE_INSTALL_FULL_DATADIR}/${RIME_DATA_DIR}")
-  set(pluginsdir "${CMAKE_INSTALL_FULL_LIBDIR}/${RIME_PLUGINS_DIR}")
-  set(includedir "${CMAKE_INSTALL_FULL_INCLUDEDIR}")
+# Android doesn't support PkgConfig yet
+if(NOT ANDROID)
   configure_file(
-      ${PROJECT_SOURCE_DIR}/rime.pc.in
-      ${PROJECT_BINARY_DIR}/rime.pc
-      @ONLY)
+    ${PROJECT_SOURCE_DIR}/rime.pc.in
+    ${PROJECT_BINARY_DIR}/rime.pc
+    @ONLY)
   install(FILES ${PROJECT_BINARY_DIR}/rime.pc
     DESTINATION ${CMAKE_INSTALL_FULL_LIBDIR}/pkgconfig)
 endif()
 
-install(FILES cmake/RimeConfig.cmake
-  DESTINATION ${CMAKE_INSTALL_FULL_DATADIR}/cmake/rime)
+set(RIME_CMAKE_INSTALL_DIR "${CMAKE_INSTALL_LIBDIR}/cmake/Rime")
+set(RIME_IS_LINUX 0)
+if(LINUX)
+  set(RIME_IS_LINUX 1)
+endif()
+
+configure_package_config_file(
+  "${PROJECT_SOURCE_DIR}/cmake/RimeConfig.cmake.in"
+  "${PROJECT_BINARY_DIR}/RimeConfig.cmake"
+  INSTALL_DESTINATION "${RIME_CMAKE_INSTALL_DIR}")
+write_basic_package_version_file(
+  "${PROJECT_BINARY_DIR}/RimeConfigVersion.cmake"
+  VERSION ${PROJECT_VERSION}
+  COMPATIBILITY SameMajorVersion)
+
+install(EXPORT RimeTargets
+  NAMESPACE Rime::
+  DESTINATION "${RIME_CMAKE_INSTALL_DIR}")
+install(FILES
+  "${PROJECT_BINARY_DIR}/RimeConfig.cmake"
+  "${PROJECT_BINARY_DIR}/RimeConfigVersion.cmake"
+  DESTINATION "${RIME_CMAKE_INSTALL_DIR}")
 
-file(GLOB rime_public_header_files ${PROJECT_SOURCE_DIR}/src/*.h)
-list(FILTER rime_public_header_files EXCLUDE REGEX .*_impl\.h$)
-install(FILES ${rime_public_header_files}
-  DESTINATION ${CMAKE_INSTALL_FULL_INCLUDEDIR})
 if(INSTALL_PRIVATE_HEADERS)
   file(GLOB rime_private_header_files
     ${PROJECT_SOURCE_DIR}/src/rime/*.h
@@ -244,21 +216,20 @@ if(INSTALL_PRIVATE_HEADERS)
   endforeach()
 endif()
 
-if(BUILD_DATA)
-  file(GLOB rime_preset_data_files ${PROJECT_SOURCE_DIR}/data/preset/*.yaml)
-  install(FILES ${rime_preset_data_files} DESTINATION ${CMAKE_INSTALL_FULL_DATADIR}/${RIME_DATA_DIR})
-endif()
-
 if(BUILD_SHARED_LIBS)
   add_definitions(-DRIME_BUILD_SHARED_LIBS)
-  set(rime_library rime)
-  if(BUILD_SEPARATE_LIBS)
-    set(rime_dict_library rime-dict)
-    set(rime_gears_library rime-gears)
-    set(rime_levers_library rime-levers)
-  endif()
-else()
-  set(rime_library rime-static)
+endif()
+
+set(rime_dict_library rime-dict)
+set(rime_gears_library rime-gears)
+set(rime_levers_library rime-levers)
+
+if(TARGET rime-plugins AND NOT DEFINED rime_plugins_library)
+  set(rime_plugins_library rime-plugins)
+endif()
+set(rime_library rime-internal-all)
+if(NOT TARGET rime-internal-all)
+  add_library(rime-internal-all INTERFACE)
 endif()
 
 add_subdirectory(plugins)
@@ -269,7 +240,10 @@ foreach(mod ${rime_plugins_modules})
   set(list "${list},Q(${mod})")
 endforeach()
 set(RIME_SETUP_EXTRA_MODULES "${list}")
-if(BUILD_SHARED_LIBS AND BUILD_SEPARATE_LIBS AND rime_plugins_objs)
+if(rime_plugins_objs AND NOT DEFINED rime_plugins_library)
+  set(rime_plugins_library rime-plugins)
+endif()
+if(BUILD_MERGED_PLUGINS AND BUILD_SHARED_LIBS AND BUILD_SEPARATE_LIBS AND rime_plugins_objs)
   set(rime_plugins_library rime-plugins)
 endif()
 
@@ -278,11 +252,11 @@ add_subdirectory(src)
 if(BUILD_SHARED_LIBS)
   add_subdirectory(tools)
 
-  if(BUILD_TEST)
+  if(BUILD_TESTING)
     add_subdirectory(test)
   endif()
 
-  if (BUILD_SAMPLE)
+  if(BUILD_SAMPLE)
     add_subdirectory(sample)
   endif()
 endif()

Dockerfile

@@ -1,4 +1,4 @@
-FROM debian:12.1
+FROM debian:13.3
 
 RUN apt update && apt install -y \
   git \
@@ -12,6 +12,7 @@ RUN apt update && apt install -y \
   libgtest-dev \
   libyaml-cpp-dev \
   libleveldb-dev \
+  libsnappy-dev \
   libmarisa-dev \
   libopencc-dev \
   liblua5.4-dev
@@ -29,7 +30,7 @@ RUN cmake -B build -G Ninja \
   -DCMAKE_BUILD_TYPE:STRING=Release \
   -DENABLE_LOGGING:BOOL=ON \
   -DBUILD_TEST:BOOL=ON \
-  -DBUILD_STATIC:BOOL=OFF \
+  -DWITH_STATIC_DEPS:BOOL=OFF \
   -DBUILD_SHARED_LIBS:BOOL=ON
 RUN cmake --build build