Repository navigation
Expand file tree
/
Copy pathCMakeLists.txt
More file actions
264 lines (228 loc) · 9.39 KB
/
Copy pathCMakeLists.txt
File metadata and controls
264 lines (228 loc) · 9.39 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
cmake_minimum_required(VERSION 3.16)
set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/cmake/Modules/")
project(offscreen)
add_executable(offscreen)
target_compile_options(offscreen PRIVATE "$<$<CONFIG:DEBUG>:-DDEBUG>")
if(MSVC)
target_compile_options(offscreen PRIVATE /Zc:preprocessor)
endif()
if(APPLE)
set(USE_GLAD_DEFAULT OFF)
else()
set(USE_GLAD_DEFAULT ON)
endif()
option(USE_GLAD "Use GLAD for OpenGL function wrangling" ${USE_GLAD_DEFAULT})
option(ENABLE_GLFW "Enable on-screen rendering using glfw" ON)
option(ENABLE_EGL "Enable EGL offscreen context" ON)
option(ENABLE_GLX "Enable GLX offscreen context" ON)
option(ENABLE_OSMESA "Enable OSMesa offscreen rendering" ON)
set(HAS_GLVND FALSE)
set(HAS_GLX FALSE)
set(HAS_EGL FALSE)
set(HAS_OSMESA FALSE)
set(HAS_CGL FALSE)
set(HAS_NSOPENGL FALSE)
set(HAS_WGL FALSE)
if(ENABLE_OSMESA)
find_package(OSMesa)
if(OSMESA_FOUND)
set(HAS_OSMESA TRUE)
target_link_libraries(offscreen OSMesa::OSMesa)
target_compile_definitions(offscreen PRIVATE HAS_OSMESA)
set(SRCS_OSMESA src/OffscreenContextOSMesa.cc)
set(USE_GLAD ON)
endif()
endif()
if(USE_GLAD)
target_compile_definitions(offscreen PRIVATE USE_GLAD)
endif()
find_package(OpenGL REQUIRED)
if(TARGET OpenGL::OpenGL)
# GLVND systems
target_link_libraries(offscreen OpenGL::OpenGL)
set(HAS_GLVND TRUE)
else()
# Non-GLVND systems
target_link_libraries(offscreen OpenGL::GL)
endif()
target_link_libraries(offscreen OpenGL::GLU)
if (ENABLE_EGL AND OpenGL_EGL_FOUND)
if (TARGET OpenGL::EGL)
# GLVND systems
target_link_libraries(offscreen OpenGL::EGL)
else()
# Non-GLVND systems
target_link_libraries(offscreen ${OPENGL_egl_LIBRARY})
endif()
set(HAS_EGL TRUE)
find_package(GBM)
if (GBM_FOUND)
target_compile_definitions(offscreen PRIVATE HAS_GBM)
target_link_libraries(offscreen GBM::GBM)
endif()
endif()
if(ENABLE_GLX AND OpenGL_GLX_FOUND)
find_package(X11 REQUIRED)
if(X11_FOUND)
if(TARGET OpenGL::OpenGL)
# For GLVND systems (non-GLVND systems have GLX included in the OpenGL libraries)
target_link_libraries(offscreen OpenGL::GLX)
endif()
set(HAS_GLX TRUE)
target_link_libraries(offscreen X11::X11)
endif()
endif()
if(ENABLE_GLFW)
find_package(glfw3 QUIET)
if(TARGET glfw OR TARGET glfw3 OR glfw3_FOUND)
if(TARGET glfw)
target_link_libraries(offscreen glfw)
else()
target_link_libraries(offscreen glfw3)
endif()
target_compile_definitions(offscreen PRIVATE ENABLE_GLFW)
else()
message(STATUS "GLFW not found, disabling on-screen GLFW backend")
set(ENABLE_GLFW OFF)
endif()
endif()
if(CMAKE_DL_LIBS)
target_link_libraries(offscreen ${CMAKE_DL_LIBS})
endif()
if(APPLE)
set(HAS_NSOPENGL TRUE)
set(HAS_CGL TRUE)
find_library(COCOA Cocoa)
target_link_libraries(offscreen ${COCOA})
set(SRCS_APPLE
src/OffscreenContextNSOpenGL.mm
src/OffscreenContextCGL.cc
)
endif(APPLE)
if(WIN32)
set(HAS_WGL TRUE)
set(SRCS_WINDOWS src/OffscreenContextWGL.cc)
endif(WIN32)
if(HAS_EGL)
set(SRCS_EGL
src/OffscreenContextEGL.cc
src/egl_utils.cc
)
add_compile_definitions(HAS_EGL ENABLE_EGL)
endif()
if(HAS_GLX)
set(SRCS_GLX
src/OffscreenContextGLX.cc
)
add_compile_definitions(HAS_GLX ENABLE_GLX)
endif()
if(ENABLE_GLFW)
set(SRCS_GLFW src/GLFWContext.cc)
endif()
set(SRCS
src/main.cc
src/CommandLine.cc
src/system-gl.cc
src/OpenGLContext.cc
src/OffscreenContext.cc
src/OffscreenContextNULL.cc
src/OffscreenContextFactory.cc
src/fbo.cc
src/render_immediate.cc
src/render_modern_ogl2.cc
src/render_modern_ogl3.cc
${SRCS_GLFW}
${SRCS_EGL}
${SRCS_GLX}
${SRCS_APPLE}
${SRCS_WINDOWS}
${SRCS_OSMESA}
)
target_sources(offscreen PRIVATE ${SRCS})
target_include_directories(offscreen PUBLIC "${CMAKE_SOURCE_DIR}/src")
if(MSVC)
# MSVC requires /std:c++20 for designated initializers
set_property(TARGET offscreen PROPERTY CXX_STANDARD 20)
else()
# Using C++17 as my RaspberryPi runs gcc=8.3 which doesn't implement <numbers>
set_property(TARGET offscreen PROPERTY CXX_STANDARD 17)
endif()
enable_testing()
add_test(NAME default_run COMMAND offscreen)
add_test(NAME fails_on_empty_context_arg COMMAND offscreen --context)
set_property(TEST fails_on_empty_context_arg PROPERTY WILL_FAIL true)
add_test(NAME fails_on_invalid_context COMMAND offscreen --context nonexistent_backend)
set_property(TEST fails_on_invalid_context PROPERTY WILL_FAIL true)
add_test(NAME fails_on_immediate_in_core_profile COMMAND offscreen --opengl 3.3 --profile core --mode immediate)
set_property(TEST fails_on_immediate_in_core_profile PROPERTY WILL_FAIL true)
add_test(NAME nullgl_test COMMAND offscreen --context nullgl)
add_test(NAME will_save_framebuffer COMMAND offscreen -o out.png)
add_test(NAME check_file_exists COMMAND ${CMAKE_COMMAND} -E cat out.png)
set_tests_properties(check_file_exists PROPERTIES DEPENDS will_save_framebuffer)
add_test(NAME custom_dimensions_save COMMAND offscreen --width 320 --height 240 -o out_320x240.png)
add_test(NAME check_custom_file_exists COMMAND ${CMAKE_COMMAND} -E cat out_320x240.png)
set_tests_properties(check_custom_file_exists PROPERTIES DEPENDS custom_dimensions_save)
if(APPLE)
add_test(NAME cgl_opengl2_immediate COMMAND offscreen --context cgl --opengl 2 --mode immediate)
add_test(NAME cgl_opengl2_modern COMMAND offscreen --context cgl --opengl 2 --mode modern)
add_test(NAME cgl_opengl3.2_core COMMAND offscreen --context cgl --opengl 3.2 --profile core)
add_test(NAME nsopengl_opengl2_immediate COMMAND offscreen --context nsopengl --opengl 2 --mode immediate)
add_test(NAME nsopengl_opengl2_modern COMMAND offscreen --context nsopengl --opengl 2 --mode modern)
add_test(NAME nsopengl_opengl3.2_core COMMAND offscreen --context nsopengl --opengl 3.2 --profile core)
endif(APPLE)
if(HAS_EGL)
add_test(NAME egl_opengl2_immediate COMMAND offscreen --context egl --opengl 2 --mode immediate)
add_test(NAME egl_opengl2_modern COMMAND offscreen --context egl --opengl 2 --mode modern)
add_test(NAME egl_gles2 COMMAND offscreen --context egl --gles 2)
add_test(NAME egl_opengl3_core COMMAND offscreen --context egl --opengl 3.3 --profile core)
add_test(NAME egl_opengl3_compat COMMAND offscreen --context egl --opengl 3.3 --profile compatibility)
add_test(NAME egl_save_framebuffer COMMAND offscreen --context egl -o out_egl.png)
add_test(NAME check_egl_file_exists COMMAND ${CMAKE_COMMAND} -E cat out_egl.png)
set_tests_properties(check_egl_file_exists PROPERTIES DEPENDS egl_save_framebuffer)
endif()
find_program(XVFB_RUN xvfb-run)
if(HAS_GLX)
set(GLX_TEST_RUNNER "")
if(XVFB_RUN)
set(GLX_TEST_RUNNER ${XVFB_RUN} -a)
endif()
add_test(NAME glx_opengl2_immediate COMMAND ${GLX_TEST_RUNNER} $<TARGET_FILE:offscreen> --context glx --opengl 2 --mode immediate)
add_test(NAME glx_opengl2_modern COMMAND ${GLX_TEST_RUNNER} $<TARGET_FILE:offscreen> --context glx --opengl 2 --mode modern)
add_test(NAME glx_opengl3_core COMMAND ${GLX_TEST_RUNNER} $<TARGET_FILE:offscreen> --context glx --opengl 3.3 --profile core)
add_test(NAME glx_opengl3_compat COMMAND ${GLX_TEST_RUNNER} $<TARGET_FILE:offscreen> --context glx --opengl 3.3 --profile compatibility)
add_test(NAME glx_save_framebuffer COMMAND ${GLX_TEST_RUNNER} $<TARGET_FILE:offscreen> --context glx -o out_glx.png)
add_test(NAME check_glx_file_exists COMMAND ${CMAKE_COMMAND} -E cat out_glx.png)
set_tests_properties(check_glx_file_exists PROPERTIES DEPENDS glx_save_framebuffer)
endif()
if(WIN32)
add_test(NAME wgl_opengl2_immediate COMMAND offscreen --context wgl --opengl 2 --mode immediate)
add_test(NAME wgl_opengl2_modern COMMAND offscreen --context wgl --opengl 2 --mode modern)
add_test(NAME wgl_opengl3_core COMMAND offscreen --context wgl --opengl 3.3 --profile core)
add_test(NAME wgl_opengl3_compat COMMAND offscreen --context wgl --opengl 3.3 --profile compatibility)
endif(WIN32)
if(HAS_OSMESA)
add_test(NAME osmesa_opengl2_immediate COMMAND offscreen --context osmesa --opengl 2 --mode immediate)
add_test(NAME osmesa_opengl2_modern COMMAND offscreen --context osmesa --opengl 2 --mode modern)
add_test(NAME osmesa_opengl3.3_core COMMAND offscreen --context osmesa --opengl 3.3 --profile core)
add_test(NAME osmesa_opengl3.3_compat COMMAND offscreen --context osmesa --opengl 3.3 --profile compatibility)
add_test(NAME osmesa_opengl4.5_core COMMAND offscreen --context osmesa --opengl 4.5 --profile core)
add_test(NAME osmesa_save_framebuffer COMMAND offscreen --context osmesa -o out_osmesa.png)
add_test(NAME check_osmesa_file_exists COMMAND ${CMAKE_COMMAND} -E cat out_osmesa.png)
set_tests_properties(check_osmesa_file_exists PROPERTIES DEPENDS osmesa_save_framebuffer)
endif(HAS_OSMESA)
message(STATUS " ")
message(STATUS "====================================")
message(STATUS "Build Configuration Summary")
message(STATUS "====================================")
message(STATUS " ")
message(STATUS "GLAD: ${USE_GLAD}")
message(STATUS "GLFW: ${ENABLE_GLFW}")
message(STATUS "Has GLVND: ${HAS_GLVND}")
message(STATUS "GLX: ${HAS_GLX}")
message(STATUS "EGL: ${HAS_EGL}")
message(STATUS "OSMesa: ${HAS_OSMESA}")
message(STATUS "CGL: ${HAS_CGL}")
message(STATUS "NSOpenGL: ${HAS_NSOPENGL}")
message(STATUS "WGL: ${HAS_WGL}")